在两个Arduino开发板之间实现红外通信的方法

风筝

在本篇帖子中，我们将探索红外技术的潜力以及如何将其与Arduino开发板一起使用。红外通信是电子设备中允许无线信息交换的常见功能。从遥控器到自动门，红外技术无处不在。了解红外通信的原理并学习如何使用它将会开辟广泛的可能性。本文将帮助您使用Arduino开发板发送和接收红外信号。我们将介绍红外通信的基础知识，包括不同的协议和代码，以及帮助您入门的实际示例。

什么是红外通信？

红外通信是一种常见、廉价且简单的无线通信技术。红外光与可见光非常相似，只是它的波长稍长。这意味着红外辐射对人眼是不可见的，使其适合数据交换。

红外通信仅限于短距离，并且需要直接视线。它也不能穿过墙壁。

由于红外的这些限制，很难跟踪通信。事实上，红外设备之间的通信通常是一对一的。因此，以这种方式传输的数据通常不加密。

当您使用红外无线控制时，红外光谱中的LED用于将数据传输到接收器。但我们周围有各种红外源。太阳、灯泡或任何其他产生热量的东西在红外光谱中都非常明亮。因此，红外接收器必须能够区分遥控器的信号和环境红外信号。为此，我们使用调制的红外信号。调制信号就像为数据分配一个模式以确保接收器可以识别它。

红外通信的常见调制是38kHz 调制。38kHz信号波的自然来源很少，因此使用该频率的红外发射器将与环境红外波不同。当您按下遥控器上的某个键时，红外发射器的LED将在几分之一秒内快速闪烁，将编码数据传输到接收器。

通过红外传输的数据（除了其主频率38kHz 外）还有自己的协议。例如，NEC 协议（曾被日本家电制造商广泛使用）以以下格式传输数据。

到目前为止，我们已经了解了红外发射器和接收器以及如何在它们之间进行通信。现在，让我们看看如何使用这种方法在两个Arduino开发板之间进行通信并在它们之间发送和接收命令。

所需的组件

●    Arduino UNO R3开发板

●    38KHz红外接收器模块

●    红外发射器模块

●    公对母跳线

两个Arduino开发板之间的红外通信的硬件电路

如前所述，我们将使用Arduino搭建两个独立的电路。第一个电路使用38kHz红外传感器接收红外信号，并使用Arduino控制器解释输入信号。第二个电路包括一个红外发射器LED模块和一个Arduino控制器，用于将红外代码发送到接收器。

以下是这是发射器的电路：

以下是接收器的电路：

红外发射器的Arduino代码

首先，下载IRremote库并安装。然后在Arduino IDE软件中复制并粘贴以下代码。

1. 
   
2. /*
   
3.   modified on AUG 23, 2023
   
4. */
   
5. 
   
6. #include <Arduino.h>
   
7. 
   
8. #define DISABLE_CODE_FOR_RECEIVER // Disables restarting receiver after each send. Saves 450 bytes program memory and 269 bytes RAM if receiving functions are not used.
   
9. //#define SEND_PWM_BY_TIMER         // Disable carrier PWM generation in software and use (restricted) hardware PWM.
   
10. //#define USE_NO_SEND_PWM           // Use no carrier PWM, just simulate an active low receiver signal. Overrides SEND_PWM_BY_TIMER definition
    
11. 
    
12. /*
    
13.    This include defines the actual pin number for pins like IR_RECEIVE_PIN, IR_SEND_PIN for many different boards and architectures
    
14. */
    
15. #include "PinDefinitionsAndMore.h"
    
16. #include <IRremote.hpp> // include the library
    
17. 
    
18. void setup() {
    
19.   pinMode(LED_BUILTIN, OUTPUT);
    
20.   Serial.begin(115200);
    
21.   pinMode(10, INPUT_PULLUP);
    
22.   pinMode(11, INPUT_PULLUP);
    
23.   pinMode(12, INPUT_PULLUP);
    
24. 
    
25.   Serial.print(F("Send IR signals at pin ")); //Printouts the IR send pin used in the chip you want.
    
26.   Serial.println(IR_SEND_PIN);
    
27. 
    
28.   //    IrSender.begin(); // Start with IR_SEND_PIN as send pin and if NO_LED_FEEDBACK_CODE is NOT defined, enable feedback LED at default feedback LED pin
    
29.   IrSender.begin(DISABLE_LED_FEEDBACK); // Start with IR_SEND_PIN as send pin and disable feedback LED at default feedback LED pin
    
30. }
    
31. 
    
32. /*
    
33.    Set up the data to be sent.
    
34.    For most protocols, the data is build up with a constant 8 (or 16 byte) address
    
35.    and a variable 8 bit command.
    
36.    There are exceptions like Sony and Denon, which have 5 bit address.
    
37. */
    
38. uint8_t saddress = 0;
    
39. uint8_t sCommand = 0;
    
40. uint8_t sRepeats = 0;
    
41. 
    
42. void loop() {
    
43.   if (digitalRead(10) == LOW)
    
44.   {
    
45.     saddress = 0x00;
    
46.     sCommand = 0x10;
    
47.     sRepeats = 1;
    
48.   }
    
49.   else if (digitalRead(11) == LOW)
    
50.   {
    
51.     saddress = 0x01;
    
52.     sCommand = 0x20;
    
53.     sRepeats = 1;
    
54.   }
    
55.   else if (digitalRead(12) == LOW)
    
56.   {
    
57.     saddress = 0x02;
    
58.     sCommand = 0x30;
    
59.     sRepeats = 1;
    
60.   }
    
61.   if (digitalRead(10) == LOW || digitalRead(11) == LOW || digitalRead(12) == LOW)
    
62.   {
    
63.     /*
    
64.       Print current send values
    
65.     */
    
66.     Serial.println();
    
67.     Serial.print(F("Send now: address=0x"));  Serial.print(saddress, HEX);
    
68.     Serial.print(F("command=0x"));            Serial.print(sCommand, HEX);
    
69.     Serial.print(F(", repeats="));            Serial.print(sRepeats);
    
70.     Serial.println();
    
71. 
    
72.     Serial.println(F("Send standard LG with 8 bit address"));
    
73.     Serial.flush();
    
74.     IrSender.sendLG(saddress, sCommand, sRepeats);
    
75.   }
    
76. 
    
77. 
    
78.   delay(1000);  // delay must be greater than 5 ms (RECORD_GAP_MICROS), otherwise the receiver sees it as one long signal
    
79. }

复制代码

该代码读取Arduino引脚10、11和12的状态，如果其中任何一个连接到GND，它会传输一条包含不同命令和不同地址的消息。使用的协议是LG。通过更改sRepeats变量，您可以设置每次传输的消息重复次数。

传输的数据也可以在串口监视器中查看。为此，您需要在Arduino IDE软件中打开，然后将波特率设置为115200。

红外接收器的Arduino代码

在Arduino IDE软件中复制并粘贴以下代码。

1. 
   
2. /*
   
3.   modified on AUG 23, 2023
   
4. */
   
5. 
   
6. /*
   
7. * Specify which protocol(s) should be used for decoding.
   
8. * If no protocol is defined, all protocols (except Bang&Olufsen) are active.
   
9. * This must be done before the #include <IRremote.hpp>
   
10. */
    
11. //#define DECODE_DENON        // Includes Sharp
    
12. //#define DECODE_JVC
    
13. //#define DECODE_KASEIKYO
    
14. //#define DECODE_PANASONIC    // alias for DECODE_KASEIKYO
    
15. #define DECODE_LG
    
16. #define DECODE_NEC          // Includes Apple and Onkyo
    
17. //#define DECODE_SAMSUNG
    
18. //#define DECODE_SONY
    
19. //#define DECODE_RC5
    
20. //#define DECODE_RC6
    
21. 
    
22. //#define DECODE_BOSEWAVE
    
23. //#define DECODE_LEGO_PF
    
24. //#define DECODE_MAGIQUEST
    
25. //#define DECODE_WHYNTER
    
26. //#define DECODE_FAST
    
27. 
    
28. //#define DECODE_DISTANCE_WIDTH // Universal decoder for pulse distance width protocols
    
29. //#define DECODE_HASH         // special decoder for all protocols
    
30. 
    
31. //#define DECODE_BEO          // This protocol must always be enabled manually, i.e. it is NOT enabled if no protocol is defined. It prevents decoding of SONY!
    
32. 
    
33. //#define DEBUG               // Activate this for lots of lovely debug output from the decoders.
    
34. 
    
35. //#define RAW_BUFFER_LENGTH  180  // Default is 112 if DECODE_MAGIQUEST is enabled, otherwise 100.
    
36. 
    
37. #include <Arduino.h>
    
38. 
    
39. /*
    
40. * This include defines the actual pin number for pins like IR_RECEIVE_PIN, IR_SEND_PIN for many different boards and architectures
    
41. */
    
42. #include "PinDefinitionsAndMore.h"
    
43. #include <IRremote.hpp> // include the library
    
44. 
    
45. void setup() {
    
46.     Serial.begin(115200);
    
47. 
    
48.     // Start the receiver and if not 3. parameter specified, take LED_BUILTIN pin from the internal boards definition as default feedback LED
    
49.     IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK);
    
50. 
    
51.     Serial.print(F("Ready to receive IR signals of protocols: "));
    
52.     printActiveIRProtocols(&Serial);
    
53.     Serial.println(F("at pin " STR(IR_RECEIVE_PIN))); //Printouts the IR receive pin used in the chip you want.
    
54. }
    
55. 
    
56. void loop() {
    
57.     /*
    
58.      * Check if received data is available and if yes, try to decode it.
    
59.      * Decoded result is in the IrReceiver.decodedIRData structure.
    
60.      */
    
61.     if (IrReceiver.decode()) {
    
62. 
    
63.         /*
    
64.          * Print a short summary of received data
    
65.          */
    
66.         IrReceiver.printIRResultShort(&Serial);
    
67.         IrReceiver.printIRSendUsage(&Serial);
    
68.         if (IrReceiver.decodedIRData.protocol == UNKNOWN) {
    
69.             Serial.println(F("Received noise or an unknown (or not yet enabled) protocol"));
    
70.             // We have an unknown protocol here, print more info
    
71.             IrReceiver.printIRResultRawFormatted(&Serial, true);
    
72.         }
    
73.         Serial.println();
    
74. 
    
75.         /*
    
76.          * !!!Important!!! Enable receiving of the next value,
    
77.          * since receiving has stopped after the end of the current received data packet.
    
78.          */
    
79.         IrReceiver.resume(); // Enable receiving of the next value
    
80. 
    
81.         /*
    
82.          * Finally, check the received data and perform actions according to the received command
    
83.          */
    
84.         if (IrReceiver.decodedIRData.command == 0x10) {
    
85.             // do something
    
86.             Serial.println("received command 10");
    
87.         } else if (IrReceiver.decodedIRData.command == 0x20) {
    
88.             // do something else
    
89.             Serial.println("received command 20");
    
90.         } else if (IrReceiver.decodedIRData.command == 0x30) {
    
91.             // do something else
    
92.             Serial.println("received command 30");
    
93.         }
    
94.     }
    
95. }

复制代码

在该代码中，Arduino开发板等待接收红外信号，如果接收到的数据格式正确，则根据其指令和地址在串口监视器上打印一条消息。

Arduino红外通信示例测试

对两个Arduino开发板进行编程后，确保发射器上的LED和红外接收器上的二极管彼此相对。现在，如果您将发射器板上的10、11或12引脚之一连接到GND，则相应的地址和命令将传输到接收器。

您可以在发射器和接收器的串行监视器上分别查看发送和接收的数据。在这里，我们通过将引脚10、11 或12连接到GND 来测试所有三种模式。如您所见，每个引脚对应的命令都已发送和接收。