查看: 87140 | 回复: 3

发表于: 2018-11-16 22:11:29 | 显示全部楼层

在本篇文章中，我们将学习如何使用HC-12无线串行通信模块，该模块能够在多个Arduino开发板之间进行远程无线通信，距离可达1.8km。其中，我列举了两个基本的例子，来解释了如何连接HC-12模块并在两个Arduinos之间进行基本通信，另外一个例子是通过使用第一个Arduino开发板上的加速计传感器，无线控制第二个Arduino开发板的步进电机的位置。

HC-12无线通信模块

首先让我们仔细看看HC-12无线串口通信模块。以下是它的一些特性：

● 其无线工作频段为433.4 MHz至473.0 MHz

● 它有100个通道，每个通道之间的步进为400 KHz

● 发射功率从-1dBm（0.79mW）到20dBm（100mW）

● 接收灵敏度从-117dBm（0.019pW）到-100dBm（10pW）。

这些值实际上取决于所选的串行和空中波特率，如下表所示。

HC-12模块有一个微控制器，实际上不需要由用户编程。对于配置模块，我们只需使用AT命令，可以从Arduino、PC或任何其他微控制器使用串口发送。要进入AT命令模式，我们只需将模块的“Set”引脚设置为低逻辑电平。

Arduino和HC-12

现在让我们将HC-12模块连接到Arduino并制作第一个示例。以下是电路原理图。模块的工作电压为3.2 V至5.5 V，为了更稳定工作，建议使用去耦电容和外部电源。但是，我使用PC USB作为本文章中所有三个示例的电源，并且没有任何问题。

我将第一个模块连接到Arduino UNO开发板，将第二个模块连接到Arduino MEGA，您也可以使用任何您想要的开发板。

以下原理图所需的组件：

● HC-12无线通信模块

● Arduino开发板

● 面包板和跳线

示例01 - Arduino代码

以下是第一个示例的Arduino代码，使用串口监视器（Serial Monitor）在两个模块之间进行基本通信。

/* Arduino Long Range Wireless Communication using HC-12
Example 01
by Dejan Nedelkovski, www.HowToMechatronics.com
*/
#include <SoftwareSerial.h>
SoftwareSerial HC12(10, 11); // HC-12 TX Pin, HC-12 RX Pin
void setup() {
Serial.begin(9600); // Serial port to computer
HC12.begin(9600); // Serial port to HC12
}
void loop() {
while (HC12.available()) { // If HC-12 has data
Serial.write(HC12.read()); // Send the data to Serial monitor
}
while (Serial.available()) { // If Serial monitor has data
HC12.write(Serial.read()); // Send that data to HC-12
}
}

复制代码

这两个Arduino开发板使用相同的代码。我们可以在两台独立的计算机上连接两个Arduino开发，但我们也可以使用一台计算机。

一旦我们将第一个Arduino开发板连接到计算机，我们需要选择型号和COM端口并将代码上传到Arduino。然后我们连接第二个Arduino，我们必须再次启动Arduino IDE，以便能够选择我们的第二个Arduino连接到的另一个COM端口，然后上传相同的代码。

因此，一旦我们运行了两个Arduino IDE，我们就可以启动串口监视器并测试通信是否正常工作。我们在串口监视器中输入的任何内容都将从一个发送到另一个Arduino。

代码如何工作：所以一旦我们在串口监视器中输入内容并单击Send按钮，在第一个Arduino上，while循环中的Serial.available()函数将变为true，然后使用HC12.write()函数我们将数据从串行监视器发送到HC-12模块。该模块将数据无线传输到第二个HC-12模块，因此在第二个Arduino时，while循环中HC12.available()函数将变为true，然后使用Serial.write()函数将数据发送到串口监视器。

我们可以使用相同的代码发送AT命令和配置模块参数。我们所要做的就是将模块的“Set”引脚连接到地或Arduino的任何数字引脚，并将引脚设置为低逻辑电平。

为了测试我们是否已成功进入该模式，在串口监视器中我们可以输入“AT”，我们应该收到响应消息“OK”。总共有12个AT命令，它们用于改变波特率、通道、发射功率等各种参数。例如，如果输入“AT + B38400”，模块的波特率将设置为38400。

AT命令：

1. AT - 测试命令。

示例：向模块发送“AT”，模块返回“OK”。

2. AT + Bxxxx - 更改串口波特率。

可用波特率：1200 bps、2400 bps、4800 bps、9600 bps、19200 bps、38400 bps、57600 bps和115200 bps。默认值：9600 bps。

示例：将“AT + B38400”发送到模块，模块返回“OK + B19200”。

3. AT + Cxxxx - 更改无线通信信道，从001到100。

默认值：通道001，工作频率为433.4MHz。每个下一个通道都高出400KHz。

示例：如果我们要将模块设置为通道006，我们需要向模块发送“AT + C006”命令，模块将返回“OK + C006”。新的工作频率为435.4MHz。

电梯直达

相关帖子

使用道具举报

风筝

发表于: 2018-11-17 08:58:31 | 显示全部楼层

沙发

示例02

现在让我们开始制作第二个例子。在该示例中，我们将使用两个按钮来选择不同的通信通道，并使用与以前不同的方法来存储传入的数据。

注意：两个HC-12模块的“Set”引脚连接到两个Arduino的引脚6，第一个Arduino的两个按钮分别连接到引脚4和引脚3。

第一个Arduino开发板的代码：

/* Arduino Long Range Wireless Communication using HC-12
Example 02 - Changing channels using push buttons - Buttons side
by Dejan Nedelkovski, www.HowToMechatronics.com
*/
#include <SoftwareSerial.h>
#define setPin 6
#define button1 4
#define button2 3
SoftwareSerial HC12(10, 11); // HC-12 TX Pin, HC-12 RX Pin
byte incomingByte;
String readBuffer = "";
int button1State = 0;
int button1Pressed = 0;
int button2State = 0;
int button2Pressed = 0;
void setup() {
Serial.begin(9600); // Open serial port to computer
HC12.begin(9600); // Open serial port to HC12
pinMode(setPin, OUTPUT);
pinMode(button1, INPUT);
pinMode(button2, INPUT);
digitalWrite(setPin, HIGH); // HC-12 normal, transparent mode
}
void loop() {
// ==== Storing the incoming data into a String variable
while (HC12.available()) { // If HC-12 has data
incomingByte = HC12.read(); // Store each icoming byte from HC-12
readBuffer += char(incomingByte); // Add each byte to ReadBuffer string variable
}
delay(100);
// ==== Sending data from one HC-12 to another via the Serial Monitor
while (Serial.available()) {
HC12.write(Serial.read());
}
// ==== If button 1 is pressed, set the channel 01
button1State = digitalRead(button1);
if (button1State == HIGH & button1Pressed == LOW) {
button1Pressed = HIGH;
delay(20);
}
if (button1Pressed == HIGH) {
HC12.print("AT+C001"); // Send the AT Command to the other module
delay(100);
//Set AT Command Mode
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print("AT+C001"); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH); // Exit AT Command mode
button1Pressed = LOW;
}
// ==== If button 2 is pressed, set the channel 02
button2State = digitalRead(button2);
if (button2State == HIGH & button2Pressed == LOW) {
button2Pressed = HIGH;
delay(100);
}
if (button2Pressed == HIGH) {
HC12.print("AT+C002"); // Send the AT Command to the other module
delay(100);
//Set AT Command Mode
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print("AT+C002"); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH);
button2Pressed = LOW;
}
checkATCommand();
readBuffer = ""; // Clear readBuffer
}
// ==== Custom function - Check whether we have received an AT Command via the Serial Monitor
void checkATCommand () {
if (readBuffer.startsWith("AT")) { // Check whether the String starts with "AT"
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(200); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
digitalWrite(setPin, HIGH); // Exit AT Command mode
}
}

复制代码

第二个Arduino开发板的代码：

/* Arduino Long Range Wireless Communication using HC-12
Example 02 - Changing channels using push buttons
by Dejan Nedelkovski, www.HowToMechatronics.com
*/
#include <SoftwareSerial.h>
#define setPin 6
SoftwareSerial HC12(10, 11); // HC-12 TX Pin, HC-12 RX Pin
byte incomingByte;
String readBuffer = "";
void setup() {
Serial.begin(9600); // Open serial port to computer
HC12.begin(9600); // Open serial port to HC12
pinMode(setPin, OUTPUT);
digitalWrite(setPin, HIGH); // HC-12 normal mode
}
void loop() {
// ==== Storing the incoming data into a String variable
while (HC12.available()) { // If HC-12 has data
incomingByte = HC12.read(); // Store each icoming byte from HC-12
readBuffer += char(incomingByte); // Add each byte to ReadBuffer string variable
}
delay(100);
// ==== Sending data from one HC-12 to another via the Serial Monitor
while (Serial.available()) {
HC12.write(Serial.read());
}
// === If button 1 is pressed, set channel 01
if (readBuffer == "AT+C001") {
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12 ("AT+C001")
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH); // Exit AT Command mode
readBuffer = "";
}
// === If button 2 is pressed, set channel 02
if (readBuffer == "AT+C002") {
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH); // Exit AT Command mode
readBuffer = "";
}
checkATCommand();
readBuffer = ""; // Clear readBuffer
}
// ==== Custom function - Check whether we have received an AT Command via the Serial Monitor
void checkATCommand () {
if (readBuffer.startsWith("AT")) { // Check whether the String starts with "AT"
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
digitalWrite(setPin, HIGH); // Exit AT Command mode
}
}

复制代码

代码说明

首先我们需要定义引脚并将“Set”引脚设置为高逻辑电平，以使模块在正常的透明模式下工作。使用第一个while循环，我们将传入的数据存储到String变量中，这样我们可以更好地处理它。

// ==== Storing the incoming data into a String variable
while (HC12.available()) { // If HC-12 has data
incomingByte = HC12.read(); // Store each icoming byte from HC-12
readBuffer += char(incomingByte); // Add each byte to ReadBuffer string variable
}

复制代码

传入的数据一次总是一个字节。举个例子，如果我们从第二个Arduino发送字符串“Test123”，这个while循环将进行7次迭代。每次迭代，使用HC12.read()函数，我们将读取每个传入的字节或字符，并将其添加到名为“readBuffer”的String变量中。

接下来让我们看看如何使用第一个按钮更改通信通道。因此，如果我们按下第一个按钮，使用HC12.print()函数，我们将字符串“AT + C001”发送到HC-12模块或第二个Arduino。

if (button1Pressed == HIGH) {
HC12.print("AT+C001"); // Send the AT Command to the other module
delay(100);
//Set AT Command Mode
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print("AT+C001"); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH); // Exit AT Command mode
button1Pressed = LOW;
}

复制代码

当在第二个Arduino接收到该字符串时，我们将HC-12模块设置为AT命令模式，然后将相同的字符串“AT + C001”写入其中，这将把模块设置为通信通道1。

// At the second Arduino
// === If button 1 is pressed, set channel 01
if (readBuffer == "AT+C001") {
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(100); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12 ("AT+C001")
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
Serial.println("Channel successfully changed");
digitalWrite(setPin, HIGH); // Exit AT Command mode
readBuffer = "";
}

复制代码

我们使用下一个while循环来打印来自HC-12模块的响应消息，无论通道是否已成功更改。

while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}

复制代码

回到第一个Arduino，我们执行将AT命令发送到第一个HC-12模块的相同过程。以同样的方式，我们使用按下第二个按钮，我们设置通信通道2。因此，使用此方法，我们可以随时选择与之沟通的HC-12模块。

最后，checkATCommand()自定义函数通过检查字符串是否以“AT”开头来检查收到的消息是否是AT命令。如果是，则模块进入AT命令模式并执行命令。

// ==== Custom function - Check whether we have received an AT Command via the Serial Monitor
void checkATCommand () {
if (readBuffer.startsWith("AT")) { // Check whether the String starts with "AT"
digitalWrite(setPin, LOW); // Set HC-12 into AT Command mode
delay(200); // Wait for the HC-12 to enter AT Command mode
HC12.print(readBuffer); // Send AT Command to HC-12
delay(200);
while (HC12.available()) { // If HC-12 has data (the AT Command response)
Serial.write(HC12.read()); // Send the data to Serial monitor
}
digitalWrite(setPin, HIGH); // Exit AT Command mode
}
}

复制代码

使用道具举报

风筝

发表于: 2018-11-17 09:30:08 | 显示全部楼层

板凳

HC-12无线通信：使用加速度计控制步进电机

现在来看看第三个例子。本示例中，我们使用第一个Arduino开发板上的加速度计模块控制第二个Arduino上的步进电机的位置。

HC-12-Wireless-Communication-Stepper-Motor-Control-using-an-Accelerometer-Example-03.jpg

该电路还包含一个微动开关，用于查出步进电机的初始位置为0度。

HC-12-Wireless-Communication-Stepper-Motor-Control-using-an-Accelerometer-Circui.png

此示例所需的组件如下：

● HC-12无线通信模块

● A4988步进电机驱动器

● 步进电机NEMA 17

● Arduino开发板

● 面包板和跳线

● 带ADXL345加速度计的GY-80电路板

第一个Arduino - 发射器代码：

/* Arduino Long Range Wireless Communication using HC-12
Example 03 - Stepper Motor Control using Accelerometer - Transmitter, Accelerometer
by Dejan Nedelkovski, www.HowToMechatronics.com
*/
#include <SoftwareSerial.h>
#include <Wire.h>
SoftwareSerial HC12(10, 11); // HC-12 TX Pin, HC-12 RX Pin
float angle;
int lastAngle = 0;
int count = 0;
int angleSum = 0;
//--- Accelerometer Register Addresses
#define Power_Register 0x2D
#define X_Axis_Register_DATAX0 0x32 // Hexadecima address for the DATAX0 internal register.
#define X_Axis_Register_DATAX1 0x33 // Hexadecima address for the DATAX1 internal register.
#define Y_Axis_Register_DATAY0 0x34
#define Y_Axis_Register_DATAY1 0x35
#define Z_Axis_Register_DATAZ0 0x36
#define Z_Axis_Register_DATAZ1 0x37
int ADXAddress = 0x53; //Device address in which is also included the 8th bit for selecting the mode, read in this case.
int X0, X1, X_out;
int Y0, Y1, Y_out;
int Z1, Z0, Z_out;
float Xa, Ya, Za;
void setup() {
HC12.begin(9600); // Open serial port to HC12
Wire.begin(); // Initiate the Wire library
Serial.begin(9600);
delay(100);
Wire.beginTransmission(ADXAddress);
Wire.write(Power_Register); // Power_CTL Register
// Enable measurement
Wire.write(8); // Bit D3 High for measuring enable (0000 1000)
Wire.endTransmission();
}
void loop() {
// X-axis
Wire.beginTransmission(ADXAddress); // Begin transmission to the Sensor
//Ask the particular registers for data
Wire.write(X_Axis_Register_DATAX0);
Wire.write(X_Axis_Register_DATAX1);
Wire.endTransmission(); // Ends the transmission and transmits the data from the two registers
Wire.requestFrom(ADXAddress, 2); // Request the transmitted two bytes from the two registers
if (Wire.available() <= 2) { //
X0 = Wire.read(); // Reads the data from the register
X1 = Wire.read();
/* Converting the raw data of the X-Axis into X-Axis Acceleration
- The output data is Two's complement
- X0 as the least significant byte
- X1 as the most significant byte */
X1 = X1 << 8;
X_out = X0 + X1;
Xa = X_out / 256.0; // Xa = output value from -1 to +1, Gravity acceleration acting on the X-Axis
}
//Serial.print("Xa= ");
//Serial.println(X_out);
// Y-Axis
Wire.beginTransmission(ADXAddress);
Wire.write(Y_Axis_Register_DATAY0);
Wire.write(Y_Axis_Register_DATAY1);
Wire.endTransmission();
Wire.requestFrom(ADXAddress, 2);
if (Wire.available() <= 2) {
Y0 = Wire.read();
Y1 = Wire.read();
Y1 = Y1 << 8;
Y_out = Y0 + Y1;
Ya = Y_out / 256.0;
}
// Combine X and Y values for getting the angle value from 0 to 180 degrees
if (Y_out > 0) {
angle = map(Y_out, 0, 256, 90, 0);
}
else if (Y_out < 0) {
angle = map(Y_out, 256, 0, 90, 0);
angle = 90 - angle;
}
if (X_out < 0 & Y_out < 0) {
angle = 180;
}
if (X_out < 0 & Y_out >0) {
angle = 0;
}
// float to int
int angleInt = int(angle);
// Makes 100 accelerometer readings and sends the average for smoother result
angleSum = angleSum + angleInt;
count++;
if (count >= 100) {
angleInt = angleSum / 100;
angleSum = 0;
count = 0;
// Some more smoothing of acceleromter reading - sends the new angle only if it differes from the previous one by +-2
if (angleInt > lastAngle + 2 || angleInt < lastAngle - 2) {
Serial.println(angleInt);
String angleString = String(angleInt);
//sends the angle value with start marker "s" and end marker "e"
HC12.print("s" + angleString + "e");
delay(10);
lastAngle = angleInt;
angleSum = 0;
count = 0;
}
}
}

复制代码

第二个Arduino - 接收器代码：

/* Arduino Long Range Wireless Communication using HC-12
Example 03 - Stepper Motor Control using Accelerometer - Receiver, Stepper Motor
by Dejan Nedelkovski, www.HowToMechatronics.com
*/
#include <SoftwareSerial.h>
SoftwareSerial HC12(10, 11); // HC-12 TX Pin, HC-12 RX Pin
char incomingByte;
String readBuffer = "";
// defines pins numbers
const int dirPin = 4;
const int stepPin = 3;
const int button = 2;
int currentAngle = 0;
int lastAngle = 0;
int rotate = 0;
void setup() {
Serial.begin(9600); // Open serial port to computer
HC12.begin(9600); // Open serial port to HC12
// Sets the two pins as Outputs
pinMode(dirPin, OUTPUT);
pinMode(stepPin, OUTPUT);
// Microswitch input, with internal pull-up resistor activated
pinMode(button, INPUT_PULLUP);
delay(10);
digitalWrite(dirPin, HIGH);
boolean startingPosition = true;
while (startingPosition) {
digitalWrite(stepPin, HIGH);
delayMicroseconds(200);
digitalWrite(stepPin, LOW);
delayMicroseconds(200);
if (digitalRead(button) == LOW) {
startingPosition = false;
}
}
delay(100);
}
void loop() {
readBuffer = "";
boolean start = false;
// Reads the incoming angle
while (HC12.available()) { // If HC-12 has data
incomingByte = HC12.read(); // Store each icoming byte from HC-12
delay(5);
// Reads the data between the start "s" and end marker "e"
if (start == true) {
if (incomingByte != 'e') {
readBuffer += char(incomingByte); // Add each byte to ReadBuffer string variable
}
else {
start = false;
}
}
// Checks whether the received message statrs with the start marker "s"
else if ( incomingByte == 's') {
start = true; // If true start reading the message
}
}
// Converts the string into integer
currentAngle = readBuffer.toInt();
// Makes sure it uses angles between 0 and 180
if (currentAngle > 0 && currentAngle < 180) {
// Convert angle value to steps (depending on the selected step resolution)
// A cycle = 200 steps, 180deg = 100 steps ; Resolution: Sixteenth step x16
currentAngle = map(currentAngle, 0, 180, 0, 1600);
//Serial.println(currentAngle); // Prints the angle on the serial monitor
digitalWrite(dirPin, LOW); // Enables the motor to move in a particular direction
// Rotates the motor the amount of steps that differs from the previous positon
if (currentAngle != lastAngle) {
if (currentAngle > lastAngle) {
rotate = currentAngle - lastAngle;
for (int x = 0; x < rotate; x++) {
digitalWrite(stepPin, HIGH);
delayMicroseconds(400);
digitalWrite(stepPin, LOW);
delayMicroseconds(400);
}
}
// rotate the other way
if (currentAngle < lastAngle) {
rotate = lastAngle - currentAngle;
digitalWrite(dirPin, HIGH); //Changes the rotations direction
for (int x = 0; x < rotate; x++) {
digitalWrite(stepPin, HIGH);
delayMicroseconds(400);
digitalWrite(stepPin, LOW);
delayMicroseconds(400);
}
}
}
lastAngle = currentAngle; // Remembers the current/ last positon
}
}

复制代码

代码说明

首先，我们在setup函数部分定义引脚并初始化模块。然后我们读取加速度计的X和Y轴的值，并将它们映射到0到180度的值。来自加速度计的值有时可能不稳定或抖动，因此为了平滑结果，我使用了100个读数的平均值。

// Makes 100 accelerometer readings and sends the average for smoother result
angleSum = angleSum + angleInt;
count++;
if (count >= 100) {
angleInt = angleSum / 100;
angleSum = 0;
count = 0;
// Some more smoothing of acceleromter reading - sends the new angle only if it differes from the previous one by +-2
if (angleInt > lastAngle + 2 || angleInt < lastAngle - 2) {
Serial.println(angleInt);
String angleString = String(angleInt);
//sends the angle value with start marker "s" and end marker "e"
HC12.print("s" + angleString + "e");
delay(10);
lastAngle = angleInt;
angleSum = 0;
count = 0;
}
}

复制代码

为了进一步平滑，只有当角度值与之前的值大于2时，我才会发送角度的新值。

请注意，当将角度值发送到HC-12模块时，我也会在前面发送字符“s”，以及后面发送字符“e”，这将在第二个Arduino接收数据时有所帮助。

在第二个Arduino开发板中，我们等到开始标记“s”到来，然后我们读取角度的值，直到结束标记“e”到达。这样我们就可以确保只收到角度的值。

// Reads the incoming angle
while (HC12.available()) { // If HC-12 has data
incomingByte = HC12.read(); // Store each icoming byte from HC-12
delay(5);
// Reads the data between the start "s" and end marker "e"
if (start == true) {
if (incomingByte != 'e') {
readBuffer += char(incomingByte); // Add each byte to ReadBuffer string variable
}
else {
start = false;
}
}
// Checks whether the received message statrs with the start marker "s"
else if ( incomingByte == 's') {
start = true; // If true start reading the message
}
}