使用Arduino IDE通过网页实现对ESP32进行空中编程（OTA）

风筝

带WiFi功能的控制器如ESP32，都带有一种绝妙的功能就是无线更新固件的能力。这种编程方式称为空中编程（OTA，Over-The-Air）。

ESP32中的OTA编程是什么？

OTA编程使您可以通过Wi-Fi更新/上传到ESP32的新程序，而无需通过USB将ESP32连接到计算机。

当没有物理访问ESP模块时，OTA功能就派上用场。此外，它减少了在维护过程中更新每个ESP模块所需的时间。

OTA的一个主要优点是，单个中间位置可以将更新发送给同一网络上的多个ESP。唯一的缺点是，您必须在上传的每个草图中包含一段OTA代码，以便在下一个更新中使用OTA。

在ESP32中实施OTA的方法

在ESP32中实现OTA功能有两种方法。

●    基本OTA  - 使用Arduino IDE提供OTA更新。

●    网页更新OTA  - 更新是通过网页浏览器提供的。

每种方式都有自己的优势，因此您可以选用最适合您项目的其中一种。

3个实现ESP32网页更新OTA的简单步骤

1.  串口上传OTA代码：第一步是上传包含OTA例程的草图。这是一个必要性的步骤，这样您能够通过OTA进行下一次更新/上传。

2.  访问网页浏览器：OTA代码以STA模式创建Web服务器，可以通过网页浏览器访问。登录到网页服务器后，您可以上传新草图。

3.  通过OTA上传新的草图：您可以通过通过网页服务器生成和上传编译的.bin文件将新草图上传到ESP32。

第1步：串口上传OTA代码

ESP32中的出厂镜像中没有OTA升级功能。因此，第一步是通过串口将OTA固件加载到ESP32上。

这是首次更新固件的必要步骤，以便您可以OTA进行下一次更新/上传。

Arduino IDE的ESP32附加组件带有OTA库和OTAWebUpdater示例。您可以通过File > Examples >ArduinoOTA > OTAWebUpdater或通过github访问它。

该默认的OTA Web Updater的UI非常丑陋，因此我们修改了代码以看起来更酷。首先，将ESP32插入计算机，然后下载以下草图。

在上传草图之前，您需要进行一些更改以使其适合您。您需要使用网络凭据修改以下两个变量，以便ESP32可以与现有网络建立连接。

1. const char* ssid = "---";
   
2. const char* password = "----";

复制代码

完成后，上传草图代码到ESP32。

1. #include <WiFi.h>
   
2. #include <WiFiClient.h>
   
3. #include <WebServer.h>
   
4. #include <ESPmDNS.h>
   
5. #include <Update.h>
   
6. 
   
7. const char* host = "esp32";
   
8. const char* ssid = "---";
   
9. const char* password = "----";
   
10. 
    
11. WebServer server(80);
    
12. 
    
13. /* Style */
    
14. String style =
    
15. "<style>#file-input,input{width:100%;height:44px;border-radius:4px;margin:10px auto;font-size:15px}"
    
16. "input{background:#f1f1f1;border:0;padding:0 15px}body{background:#3498db;font-family:sans-serif;font-size:14px;color:#777}"
    
17. "#file-input{padding:0;border:1px solid #ddd;line-height:44px;text-align:left;display:block;cursor:pointer}"
    
18. "#bar,#prgbar{background-color:#f1f1f1;border-radius:10px}#bar{background-color:#3498db;width:0%;height:10px}"
    
19. "form{background:#fff;max-width:258px;margin:75px auto;padding:30px;border-radius:5px;text-align:center}"
    
20. ".btn{background:#3498db;color:#fff;cursor:pointer}</style>";
    
21. 
    
22. /* Login page */
    
23. String loginIndex =
    
24. "<form name=loginForm>"
    
25. "<h1>ESP32 Login</h1>"
    
26. "<input name=userid placeholder='User ID'> "
    
27. "<input name=pwd placeholder=Password type=Password> "
    
28. "<input type=submit onclick=check(this.form) class=btn value=Login></form>"
    
29. "<script>"
    
30. "function check(form) {"
    
31. "if(form.userid.value=='admin' && form.pwd.value=='admin')"
    
32. "{window.open('/serverIndex')}"
    
33. "else"
    
34. "{alert('Error Password or Username')}"
    
35. "}"
    
36. "</script>" + style;
    
37. 
    
38. /* Server Index Page */
    
39. String serverIndex =
    
40. "<script src='https://ajax.googleapis.com/ajax/libs/jquery/3.2.1/jquery.min.js'></script>"
    
41. "<form method='POST' action='#' enctype='multipart/form-data' id='upload_form'>"
    
42. "<input type='file' name='update' id='file' onchange='sub(this)' style=display:none>"
    
43. "<label id='file-input' for='file'>   Choose file...</label>"
    
44. "<input type='submit' class=btn value='Update'>"
    
45. "<br><br>"
    
46. "<div id='prg'></div>"
    
47. "<br><div id='prgbar'><div id='bar'></div></div><br></form>"
    
48. "<script>"
    
49. "function sub(obj){"
    
50. "var fileName = obj.value.split('\\\\');"
    
51. "document.getElementById('file-input').innerHTML = '   '+ fileName[fileName.length-1];"
    
52. "};"
    
53. "$('form').submit(function(e){"
    
54. "e.preventDefault();"
    
55. "var form = $('#upload_form')[0];"
    
56. "var data = new FormData(form);"
    
57. "$.ajax({"
    
58. "url: '/update',"
    
59. "type: 'POST',"
    
60. "data: data,"
    
61. "contentType: false,"
    
62. "processData:false,"
    
63. "xhr: function() {"
    
64. "var xhr = new window.XMLHttpRequest();"
    
65. "xhr.upload.addEventListener('progress', function(evt) {"
    
66. "if (evt.lengthComputable) {"
    
67. "var per = evt.loaded / evt.total;"
    
68. "$('#prg').html('progress: ' + Math.round(per*100) + '%');"
    
69. "$('#bar').css('width',Math.round(per*100) + '%');"
    
70. "}"
    
71. "}, false);"
    
72. "return xhr;"
    
73. "},"
    
74. "success:function(d, s) {"
    
75. "console.log('success!') "
    
76. "},"
    
77. "error: function (a, b, c) {"
    
78. "}"
    
79. "});"
    
80. "});"
    
81. "</script>" + style;
    
82. 
    
83. /* setup function */
    
84. void setup(void) {
    
85.   Serial.begin(115200);
    
86. 
    
87.   // Connect to WiFi network
    
88.   WiFi.begin(ssid, password);
    
89.   Serial.println("");
    
90. 
    
91.   // Wait for connection
    
92.   while (WiFi.status() != WL_CONNECTED) {
    
93.     delay(500);
    
94.     Serial.print(".");
    
95.   }
    
96.   Serial.println("");
    
97.   Serial.print("Connected to ");
    
98.   Serial.println(ssid);
    
99.   Serial.print("IP address: ");
    
100.   Serial.println(WiFi.localIP());
     
101. 
     
102.   /*use mdns for host name resolution*/
     
103.   if (!MDNS.begin(host)) { //http://esp32.local
     
104.     Serial.println("Error setting up MDNS responder!");
     
105.     while (1) {
     
106.       delay(1000);
     
107.     }
     
108.   }
     
109.   Serial.println("mDNS responder started");
     
110.   /*return index page which is stored in serverIndex */
     
111.   server.on("/", HTTP_GET, []() {
     
112.     server.sendHeader("Connection", "close");
     
113.     server.send(200, "text/html", loginIndex);
     
114.   });
     
115.   server.on("/serverIndex", HTTP_GET, []() {
     
116.     server.sendHeader("Connection", "close");
     
117.     server.send(200, "text/html", serverIndex);
     
118.   });
     
119.   /*handling uploading firmware file */
     
120.   server.on("/update", HTTP_POST, []() {
     
121.     server.sendHeader("Connection", "close");
     
122.     server.send(200, "text/plain", (Update.hasError()) ? "FAIL" : "OK");
     
123.     ESP.restart();
     
124.   }, []() {
     
125.     HTTPUpload& upload = server.upload();
     
126.     if (upload.status == UPLOAD_FILE_START) {
     
127.       Serial.printf("Update: %s\n", upload.filename.c_str());
     
128.       if (!Update.begin(UPDATE_SIZE_UNKNOWN)) { //start with max available size
     
129.         Update.printError(Serial);
     
130.       }
     
131.     } else if (upload.status == UPLOAD_FILE_WRITE) {
     
132.       /* flashing firmware to ESP*/
     
133.       if (Update.write(upload.buf, upload.currentSize) != upload.currentSize) {
     
134.         Update.printError(Serial);
     
135.       }
     
136.     } else if (upload.status == UPLOAD_FILE_END) {
     
137.       if (Update.end(true)) { //true to set the size to the current progress
     
138.         Serial.printf("Update Success: %u\nRebooting...\n", upload.totalSize);
     
139.       } else {
     
140.         Update.printError(Serial);
     
141.       }
     
142.     }
     
143.   });
     
144.   server.begin();
     
145. }
     
146. 
     
147. void loop(void) {
     
148.   server.handleClient();
     
149.   delay(1);
     
150. }

复制代码

第2步：访问网页服务器

OTA Web Updater草图以STA模式创建Web服务器，该服务器可以通过网页浏览器访问，并用于将新草图上传到您的ESP32。

为了访问网页服务器，请以115200的波特率打开串口监视器。然后按ESP32上的EN按钮。如果一切正常，它将输出从路由器获得的动态IP地址。

接下来，打开浏览器，并将其指向串口显示器上显示的IP地址。ESP32应提供一个网页，要求登录凭据。

输入用户ID和密码：

用户ID：admin

密码：admin

如果您想更改用户ID和密码，请在草图中更改以下代码。

1. "if(form.userid.value=='admin' && form.pwd.value=='admin')"
   

复制代码

登录到系统后，您将被重定向到 /ServerIndex页面。此页面使您可以将新草图上传到ESP32。上传的新草图应采用符合的.bin二进制格式。

第3步：上传新草图

您需要在上传的每个草图中添加OTA Web Updater代码。否则，您将失去OTA功能，并且将无法进行OTA下载。因此，建议修改上述代码以包括您的新代码。

例如，我们将在OTA Web Updater代码中包含一个简单的LED闪烁草图。

1. #include <WiFi.h>
   
2. #include <WiFiClient.h>
   
3. #include <WebServer.h>
   
4. #include <ESPmDNS.h>
   
5. #include <Update.h>
   
6. 
   
7. const char* host = "esp32";
   
8. const char* ssid = "---";
   
9. const char* password = "----";
   
10. 
    
11. //variabls for blinking an LED with Millis
    
12. const int led = 2; // ESP32 Pin to which onboard LED is connected
    
13. unsigned long previousMillis = 0;  // will store last time LED was updated
    
14. const long interval = 1000;  // interval at which to blink (milliseconds)
    
15. int ledState = LOW;  // ledState used to set the LED
    
16. 
    
17. WebServer server(80);
    
18. 
    
19. /* Style */
    
20. String style =
    
21. "<style>#file-input,input{width:100%;height:44px;border-radius:4px;margin:10px auto;font-size:15px}"
    
22. "input{background:#f1f1f1;border:0;padding:0 15px}body{background:#3498db;font-family:sans-serif;font-size:14px;color:#777}"
    
23. "#file-input{padding:0;border:1px solid #ddd;line-height:44px;text-align:left;display:block;cursor:pointer}"
    
24. "#bar,#prgbar{background-color:#f1f1f1;border-radius:10px}#bar{background-color:#3498db;width:0%;height:10px}"
    
25. "form{background:#fff;max-width:258px;margin:75px auto;padding:30px;border-radius:5px;text-align:center}"
    
26. ".btn{background:#3498db;color:#fff;cursor:pointer}</style>";
    
27. 
    
28. /* Login page */
    
29. String loginIndex =
    
30. "<form name=loginForm>"
    
31. "<h1>ESP32 Login</h1>"
    
32. "<input name=userid placeholder='User ID'> "
    
33. "<input name=pwd placeholder=Password type=Password> "
    
34. "<input type=submit onclick=check(this.form) class=btn value=Login></form>"
    
35. "<script>"
    
36. "function check(form) {"
    
37. "if(form.userid.value=='admin' && form.pwd.value=='admin')"
    
38. "{window.open('/serverIndex')}"
    
39. "else"
    
40. "{alert('Error Password or Username')}"
    
41. "}"
    
42. "</script>" + style;
    
43. 
    
44. /* Server Index Page */
    
45. String serverIndex =
    
46. "<script src='https://ajax.googleapis.com/ajax/libs/jquery/3.2.1/jquery.min.js'></script>"
    
47. "<form method='POST' action='#' enctype='multipart/form-data' id='upload_form'>"
    
48. "<input type='file' name='update' id='file' onchange='sub(this)' style=display:none>"
    
49. "<label id='file-input' for='file'>   Choose file...</label>"
    
50. "<input type='submit' class=btn value='Update'>"
    
51. "<br><br>"
    
52. "<div id='prg'></div>"
    
53. "<br><div id='prgbar'><div id='bar'></div></div><br></form>"
    
54. "<script>"
    
55. "function sub(obj){"
    
56. "var fileName = obj.value.split('\\\\');"
    
57. "document.getElementById('file-input').innerHTML = '   '+ fileName[fileName.length-1];"
    
58. "};"
    
59. "$('form').submit(function(e){"
    
60. "e.preventDefault();"
    
61. "var form = $('#upload_form')[0];"
    
62. "var data = new FormData(form);"
    
63. "$.ajax({"
    
64. "url: '/update',"
    
65. "type: 'POST',"
    
66. "data: data,"
    
67. "contentType: false,"
    
68. "processData:false,"
    
69. "xhr: function() {"
    
70. "var xhr = new window.XMLHttpRequest();"
    
71. "xhr.upload.addEventListener('progress', function(evt) {"
    
72. "if (evt.lengthComputable) {"
    
73. "var per = evt.loaded / evt.total;"
    
74. "$('#prg').html('progress: ' + Math.round(per*100) + '%');"
    
75. "$('#bar').css('width',Math.round(per*100) + '%');"
    
76. "}"
    
77. "}, false);"
    
78. "return xhr;"
    
79. "},"
    
80. "success:function(d, s) {"
    
81. "console.log('success!') "
    
82. "},"
    
83. "error: function (a, b, c) {"
    
84. "}"
    
85. "});"
    
86. "});"
    
87. "</script>" + style;
    
88. 
    
89. /* setup function */
    
90. void setup(void) {
    
91. 
    
92. pinMode(led,  OUTPUT);
    
93. 
    
94.   Serial.begin(115200);
    
95. 
    
96.   // Connect to WiFi network
    
97.   WiFi.begin(ssid, password);
    
98.   Serial.println("");
    
99. 
    
100.   // Wait for connection
     
101.   while (WiFi.status() != WL_CONNECTED) {
     
102.     delay(500);
     
103.     Serial.print(".");
     
104.   }
     
105.   Serial.println("");
     
106.   Serial.print("Connected to ");
     
107.   Serial.println(ssid);
     
108.   Serial.print("IP address: ");
     
109.   Serial.println(WiFi.localIP());
     
110. 
     
111.   /*use mdns for host name resolution*/
     
112.   if (!MDNS.begin(host)) { //http://esp32.local
     
113.     Serial.println("Error setting up MDNS responder!");
     
114.     while (1) {
     
115.       delay(1000);
     
116.     }
     
117.   }
     
118.   Serial.println("mDNS responder started");
     
119.   /*return index page which is stored in serverIndex */
     
120.   server.on("/", HTTP_GET, []() {
     
121.     server.sendHeader("Connection", "close");
     
122.     server.send(200, "text/html", loginIndex);
     
123.   });
     
124.   server.on("/serverIndex", HTTP_GET, []() {
     
125.     server.sendHeader("Connection", "close");
     
126.     server.send(200, "text/html", serverIndex);
     
127.   });
     
128.   /*handling uploading firmware file */
     
129.   server.on("/update", HTTP_POST, []() {
     
130.     server.sendHeader("Connection", "close");
     
131.     server.send(200, "text/plain", (Update.hasError()) ? "FAIL" : "OK");
     
132.     ESP.restart();
     
133.   }, []() {
     
134.     HTTPUpload& upload = server.upload();
     
135.     if (upload.status == UPLOAD_FILE_START) {
     
136.       Serial.printf("Update: %s\n", upload.filename.c_str());
     
137.       if (!Update.begin(UPDATE_SIZE_UNKNOWN)) { //start with max available size
     
138.         Update.printError(Serial);
     
139.       }
     
140.     } else if (upload.status == UPLOAD_FILE_WRITE) {
     
141.       /* flashing firmware to ESP*/
     
142.       if (Update.write(upload.buf, upload.currentSize) != upload.currentSize) {
     
143.         Update.printError(Serial);
     
144.       }
     
145.     } else if (upload.status == UPLOAD_FILE_END) {
     
146.       if (Update.end(true)) { //true to set the size to the current progress
     
147.         Serial.printf("Update Success: %u\nRebooting...\n", upload.totalSize);
     
148.       } else {
     
149.         Update.printError(Serial);
     
150.       }
     
151.     }
     
152.   });
     
153.   server.begin();
     
154. }
     
155. 
     
156. void loop(void) {
     
157.   server.handleClient();
     
158.   delay(1);
     
159. 
     
160. //loop to blink without delay
     
161. unsigned long currentMillis = millis();
     
162. if (currentMillis - previousMillis >= interval) {
     
163. // save the last time you blinked the LED
     
164. previousMillis = currentMillis;
     
165. // if the LED is off turn it on and vice-versa:
     
166. ledState = not(ledState);
     
167. // set the LED with the ledState of the variable:
     
168. digitalWrite(led,  ledState);
     
169. }
     
170. 
     
171. }

复制代码

在Arduino IDE中生成.bin文件

为了将新草图上传到ESP32，我们需要先生成草图的二进制.bin文件。

为此，请转到Sketch > Export compiled Binary

草图成功编译后，就会在草图文件夹中生成.bin文件。 转到Sketch > Show Sketch Folder。

将新的草图通过OTA更新到ESP32

生成.bin文件后，您现在就可以将新草图上传到ESP32。

在浏览器中打开/serverIndex 页面。 单击Choose File… 选择生成的.bin文件，然后单击Update。

在几秒钟内，新草图将上传完成。这时板载的LED灯会开始闪烁。