查看: 56875 | 回复: 0

发表于: 2020-3-18 08:49:08 | 显示全部楼层

如果您曾经使用过电池、SMPS电路或其他电源电路，那么经常会发生这种情况，您必须通过加载负载来测试电源，以检查其在不同负载条件下的性能。通常用于执行此类测试的设备称为“恒定电流直流负载（Constant Current DC Load）”，它使我们能够调整电源的输出电流，然后保持恒定，直到再次调整为止。在本篇文章中，我们将学习如何使用Arduino开发板制作我们自己的可调电子负载，该负载可以接受24V的最大输入电压和高达5A的漏极电流。

在之前的压控电流源帖子中，我们已经说明了如何将运算放大器与MOSFET一起使用以及如何使用压控电流源电路。但是在本文中，我们将应用该电路制作一个数控电流源。显然，一个数字控制的电流源需要一个数字电路，因此使用了Arduino NANO。 Arduino NANO将提供直流负载所需的控件。

该电路包括三个部分。第一部分是Arduino Nano部分，第二部分是数模转换器，第三部分是纯模拟电路，使用双运算放大器来控制负载部分。

我们的电子负载具有以下输入和输出部分。

● 两个输入开关，用于增加和减少负载。

● LCD将显示设置的负载，实际负载和负载电压。

● 最大负载电流限制为5A。

● 负载的最大输入电压为24V。

所需的组件

以下列出了制作直流电子负载所需的组件。

● Arduino nano开发板

● 1602字符LCD

● Mosfet irf540n

● mcp4921数模转换器

● 5瓦并联电阻

Arduino直流电子负载电路图

在下面的示意图中，运算放大器具有两个部分。一部分是控制MOSFET，另一部分是放大检测到的电流。第一部分使用R12、R13和MOSFET。 R12用于减小反馈部分的负载效应，R13用作Mosfet栅极电阻。

电阻R8和R9用于感测此虚拟负载将承受的电源电压。根据分压器规则，这两个电阻最大支持24V。超过24V的电压会产生不适用于Arduino引脚的电压。因此请注意不要连接输出电压超过24V的电源。

电阻R7是此处的实际负载电阻。这是一个5W、0.1欧姆的电阻器。根据电源法则，它将支持最大7A（P = I2R），但是出于安全考虑，将最大负载电流限制为5A是比较明智的。因此，在目前最大24V的情况下，可以通过该虚拟负载设置5A负载。

放大器的另一部分配置为增益放大器。它将提供6倍的增益。在电流流动期间，将出现电压降。例如，当5A电流流经电阻时，根据欧姆定律，0.1欧姆分流电阻两端的电压降将为0.5V（V = I x R）。同相放大器会将其放大到x6，因此放大器第二部分的输出将为3V。该输出将由Arduino nano模拟输入引脚感测，并且将计算电流。

放大器的第一部分配置为电压跟随器电路，该电压跟随器电路将根据输入电压控制MOSFET，并由于流经分流电阻器的负载电流而获得所需的反馈电压。

MCP4921是数模转换器。 DAC使用SPI通信协议从任何微控制器单元获取数字数据，并根据其提供模拟电压输出。该电压是运算放大器的输入。

另一部分是Arduino Nano开发，它将通过SPI协议将数字数据提供给DAC并控制负载，并以1602字符显示屏显示数据。使用了另外减少和增加按钮，并没有连接到数字引脚，而是连接到模拟引脚。因此，可以将其更改为另一种类型的开关，例如滑块或模拟编码器。同样，通过修改代码，人们可以提供原始模拟数据来控制负载。这也避免了开关反跳问题。

最后，通过增加负载，Arduino nano将以数字格式将负载数据提供给DAC，DAC将向运算放大器提供模拟数据，并且运算放大器将根据运算放大器的输入电压控制MOSFET。最后，根据流经分流电阻的负载电流，将出现压降，该压降将由LM358的第二个通道进一步放大并由Arduino nano获得。这将显示在字符显示屏上。当用户按下减少按钮时，将会发生同样的事情。

PCB设计和Gerber文件

由于该电路的电流较大，因此，使用适当的PCB设计策略来消除不希望的故障情况是一个明智的选择。因此，为此直流负载设计了一个PCB。我使用Eagle PCB设计软件来设计PCB。您可以选择任何PCB Cad软件。下图显示了CAD软件中最终设计的PCB：

在设计此PCB时要注意的一个重要因素是使用厚的电源层以确保整个电路中都有适当的电流通过。还有接地拼接VIAS，用于在上下两层中正确地接地。

您也可以从下面的链接下载此PCB的Gerber文件，并将其用于生产PCB：可调式电子直流负载的Gerber文件。

可调直流负载的Arduino代码

代码很简单。首先，我们包含了SPI和LCD头文件，并设置了最大逻辑电压、芯片选择引脚等。

#include <SPI.h>
#include <LiquidCrystal.h>
#define SS_PIN 10
#define MAX_VOLT 5.0 // maximum logic voltage
#define load_resistor 0.1 // shunt resistor value in Ohms
#define opamp_gain 6 // gain of the op-amp
#define average 10 // average time

复制代码

然后声明与程序流有关的整数和变量。此外，我们设置了Arduino Nano相关的外设引脚。

const int slaveSelectPin = 10; // Chip select pin
int number = 0;
int increase = A2; // Increase pin
int decrease = A3; //decrease pin
int current_sense = A0; //current sense pin
int voltage_sense = A1; // voltage sense pin
int state1 = 0;
int state2 = 0;
int Set = 0;
float volt = 0;
float load_current = 0.0;
float load_voltage = 0.0;
float current = 0.0;
float voltage = 0.0;
LiquidCrystal lcd(7, 6, 5, 4, 3, 2); // LCD pins

复制代码

在setup函数中设置于LCD和SPI的引脚方向。

void setup() {
pinMode(slaveSelectPin, OUTPUT);
pinMode(increase, INPUT);
pinMode(decrease, INPUT);
pinMode(current_sense, INPUT);
pinMode(voltage_sense, INPUT);
// initialize SPI:
SPI.begin();
//set up the LCD's number of columns and rows:
lcd.begin(16, 2);
// Print a message to the LCD.
lcd.print("Digital Load");
lcd.setCursor(0, 1);
lcd.print("Circuit Digest");
delay (2000);
}

复制代码

以下函数用于转换DAC值。

void convert_DAC(unsigned int value)
{
/*Step Size = 2^n, Therefore 12bit 2^12 = 4096
For 5V reference, the step will be 5/4095 = 0.0012210012210012V or 1mV (approx)*/
unsigned int container ;
unsigned int MSB;
unsigned int LSB;
/*Step: 1, stored the 12 bit data into the container
Suppose the data is 4095, in binary 1111 1111 1111*/
container = value;
/*Step: 2 Creating Dummy 8 bit. So, by dividing 256, upper 4 bits are captured in LSB
LSB = 0000 1111*/
LSB = container/256;
/*Step: 3 Sending the configuration with punching the 4 bit data.
LSB = 0011 0000 OR 0000 1111. Result is 0011 1111 */
LSB = (0x30) | LSB;
/*Step:4 Container still has the 21bit value. Extracting the lower 8 bits.
1111 1111 AND 1111 1111 1111. Result is 1111 1111 which is MSB*/
MSB = 0xFF & container;
/*Step:4 Sending the 16bits data by dividing into two bytes. */
digitalWrite(slaveSelectPin, LOW);
delay(100);
SPI.transfer(LSB);
SPI.transfer(MSB);
delay(100);
// take the SS pin high to de-select the chip:
digitalWrite(slaveSelectPin, HIGH);
}

复制代码

read_current()函数用于读取感测到的电流。

float read_current (void){
load_current = 0;
for (int a = 0; a < average; a++){
load_current = load_current + analogRead(current_sense);
}
load_current = load_current / average;
load_current = (load_current* MAX_VOLT) / 1024;
load_current = (load_current / opamp_gain) / load_resistor;
return load_current;
}

复制代码

read_voltage()函数用于读取负载电压。

float read_voltage (void){
load_voltage = 0;
for (int a = 0; a < average; a++){
load_voltage = load_voltage + analogRead(voltage_sense);
}
load_voltage = load_voltage / average;
load_voltage = ((load_voltage * MAX_VOLT)/1024.0)*6;
return load_voltage;
}

复制代码

以下是loop函数的代码。在这里，测量开关，并将数据发送到DAC。传输数据后，将测量实际电流和负载电压。这两个值最终也都打印在LCD上。

void loop () {
state1 = analogRead(increase);
if (state1 > 500){
delay(50);
state1 = analogRead(increase);
if (state1 > 500){
volt = volt+0.02;
}
}
state2 = analogRead(decrease);
if (state2 > 500){
delay(50);
state2 = analogRead(decrease);
if (state2 > 500){
if (volt == 0){
volt = 0;
}
else{
volt = volt-0.02;
}
}
}
number = volt / 0.0012210012210012;
convert_DAC (number);
voltage = read_voltage();
current = read_current();
lcd.setCursor(0, 0);
lcd.print("Set Value");
lcd.print("=");
Set = (volt/2)*10000;
lcd.print(Set);
lcd.print("mA ");
lcd.setCursor(0, 1);
lcd.print("I");
lcd.print("=");
lcd.print(current);
lcd.print("A ");
lcd.print(" V");
lcd.print("=");
lcd.print(voltage);
lcd.print("V");
// lcd.print(load_voltage);
//lcd.print("mA ");
// delay(1000);
//lcd.clear();
}

复制代码

测试我们的可调直流负载

数字负载电路使用12V电源焊接并上电。我在电源侧使用了7.4V锂电池，并连接了钳型表以检查其工作情况。如您所见，当设定电流为300mA时，电路将从电池中汲取300mA电流，该电流也由钳形表测量为310mA。

希望您理解该项目，如果您有任何疑问，可以在本帖下面留言。

代码

以下是本文使用的完整代码： main.rar (1.46 KB, 下载次数: 27)

电梯直达

使用Arduino开发板自制可调电子直流负载 [复制链接]

相关帖子

Arduino专区

精彩推荐